{ inputs, config, ... }:
let
  hostname = "dnsc-server";
  secretsDir = "${inputs.self}/secrets";
in
{
  flake.nixosConfigurations.${hostname} = inputs.nixpkgs.lib.nixosSystem {
    system = "x86_64-linux";
    modules = with config.flake.modules.nixos; [
      inputs.agenix.nixosModules.default
      home-manager
      base
      git
      ssh
      zfs
      ups
      cli-tools
      nix
      jellyfin
      restic
      samba-share

      ({ config, ... }: {
        imports = [ ./_hardware-configuration.nix ];
        networking.hostName = hostname;
        networking.hostId = "e5d5a602";
        system.stateVersion = "24.11";

        # Secrets for this machine
        age = {
          identityPaths = [
            "${config.users.users.dennis.home}/.ssh/id_ed25519"
          ];
          secrets."restic/password" = {
            file = "${secretsDir}/restic/password.age";
          };
        };

        # Options for my custom modules
        samba-share.path = "/main/share";
        samba-share.allowedHosts = "192.168.178. 127.0.0.1 localhost";
      })
    ];
  };
}